let

    // Connect to the parent folder holding all files and subfolders
    Source = Folder.Files("C:\Camtasia Projects\Power Query - Avoid Scary Queries"),

    // Standardize the casing of the file extensions (using UPPERCASE)
    Uppercase_File_Extensions = Table.TransformColumns(Source,{{"Extension", Text.Upper, type text}}),

    // Filter to keep only files in the "CSV Files" folder and subfolders
    Filter_By_Path = Table.SelectRows(Uppercase_File_Extensions, each Text.Contains([Folder Path], "\CSV Files\")),

    // Filter to keep only CSV files
    Filter_By_CSV_Files = Table.SelectRows(Filter_By_Path, each Text.Contains([Extension], ".CSV")),

    // Remove all columns of folder metadata EXCEPT the [Content] column
    Keep_Only_Content = Table.SelectColumns(Filter_By_CSV_Files,{"Content"}),

    // Extract the tables from the Binary files
    Extract_Tables = Table.AddColumn(Keep_Only_Content, "CSV_Data", each Csv.Document([Content])),

    // Delete the [Content] column (column of Binaries)
    Delete_Binaries = Table.RemoveColumns(Extract_Tables,{"Content"}),

    // Expand the table columns of data from the [CSV Data] column
    Expand_Tables = Table.ExpandTableColumn(Delete_Binaries, "CSV_Data", {"Column1", "Column2", "Column3", "Column4"}, {"Column1", "Column2", "Column3", "Column4"}),

    // Promote the first row of data to a Header Row position
    Promoted_Headers = Table.PromoteHeaders(Expand_Tables, [PromoteAllScalars=true]),

    // Set the Data Types for the columns
    Set_Data_Types = Table.TransformColumnTypes(Promoted_Headers,{{"TranDate", type date}, {"Account", Int64.Type}, {"Dept", Int64.Type}, {"Sum of Amount", Currency.Type}}),

    // Remove any redundant headers and total rows (rows with text are rendered as errors by previous step)
    Remove_Error_Rows = Table.RemoveRowsWithErrors(Set_Data_Types, {"TranDate", "Account", "Dept", "Sum of Amount"})

in

    Remove_Error_Rows